//run("Install...", "install=/home/standa/Plocha/New_.ijm");

var i = 0;
var wd = "";
var export;
var lw = 10;

var lei = false;
var gauss = 1.0;
var delim = "_-";
var ex = "0 1 2 3";

var calibration = "Results";
var fileModel = "model";
var plotModel = false;
var model = "";
var pdfModel = false;
var plotWidth = 800;
var plotHeight = 600;

var selectData = "Results";
var selectModel = "Recently created";
var fileDistrib = "distrib";
var plotDistrib = false;
var variantsBoxplot = newArray(true, false, false, false, false);
var pdfDistrib = false;


var sys = getInfo("os.name");
var r = ""
var filtering = "filtered <- profile";
var cutOff = 0.2;
var filterDistrib = true;
var filterProfile = false;
var filterModel = false;

var filterPlot = false;
var selectPlot = "Results";
var variantsPlot = newArray(true, false, false, false, false, false);
var filePlot = "plot";
var pdfPlot = false;
	

var filterChannel = newArray("GFP", "FM4", "FM4");
var filterMode = newArray("bellow", "bellow", "above");
var filterX0 = newArray("0", "0", "0");
var filterY0 = newArray("1", "1", "1");

var filterX = newArray("0", "0", "0");
var filterY = newArray("1", "1", "1");

var predFrom = -1.5;
var predTo = 1.5;
var predStep = 0.1;
var lambdaExGFP = 0.488;
var lambdaExFM4 = 0.514;
var lambdaEmGFP = 0.520;
var lambdaEmFM4 = 0.800;





macro "Import options [f1]" {
	//print("Adjust an image scale and a colour mode for Leica .lei images");
	do {	
		Dialog.create("Import options");
		Dialog.addCheckbox("Leica .lei images", lei);
		Dialog.addNumber("Gaussian blur radius (px):", gauss);
		Dialog.addNumber("Profile line width (px):", lw);
		Dialog.addMessage("Image title parsing");
		Dialog.addString("Parsing delimiters", delim, 3);
		Dialog.addString("Exported items", ex);
		Dialog.addMessage("Image titles will be splited around specified characters\ninto set of items, from which the selected will be used\nas sample grouping factors.");
		if (matches(sys, ".*Windows.*")) {
			a = exec("WHERE /R \"c:\\Program Files\" R.exe");
			b = split(a,"\n");
			r = b[0];
			Dialog.addString("Path to R.exe", r);
		}
		Dialog.show();
		lei = Dialog.getCheckbox();
		gauss = Dialog.getNumber();
		lw = Dialog.getNumber();
		delim = Dialog.getString();
		ex = Dialog.getString();
		export = split(ex);
		if (matches(sys, ".*Windows.*")) {
			r = Dialog.getString();
		}
		
		selectImage(1);
		if (delim!="") {
			title = split(getTitle(), delim);
		}
		else {
			title = newArray(1);
			title[0] = getTitle();
		}
		for (e=0; e < export.length; e++) if (parseInt(export[e]) < title.length) String.append(title[parseInt(export[e])]+" .. ");


		OK = getBoolean("Parsing example:\nSamples\n"+String.buffer+"\nwill be exported", "OK", "Back");
		String.resetBuffer;
	} while (OK==false);
	
	run("Clear Results");
	run("Line Width...", "line="+lw);
	
	for (j=1; j<=nImages; j++) {
		selectImage(j);
		if (lei==true) {
			// Image info collecting, developed for .lei file only
			p = split(getImageInfo(),'\n\n');
			sti =split(getTitle());
			print("Working on image ... "+sti[2]);
			// Searching for a line with real width value... 
			for (k=0; k < lengthOf(p); k++) {
				l = split(p[k], '=');
				if (l[0] == sti[2]+" Dim0 physical length ") {
					sdim = split(l[1], ' ');
					realwidth = 1000000*sdim[0];
					print("Real width = "+realwidth+" um");
					}
				}
			sirka = getWidth();
			run("Set Scale...", "distance=sirka known=realwidth pixel=1 unit=um");
			}
		// LUTs and colour mode setting...
		run("Green");
		run("Next Slice [>]");
		run("Magenta");
		run("Previous Slice [<]");
		Stack.setDisplayMode("composite");
		run("Gaussian Blur...", "sigma="+gauss);
		t = getTitle();
		setResult("Title",j-1,t);
		if (delim!="") {
			title = split(t, delim);
		}
		else {
			title = newArray(1);
			title[0] = t;
		}
		for (e=0; e < export.length; e++) if (parseInt(export[e]) < title.length) setResult(e,j-1,title[export[e]]);
		}
		updateResults;
		IJ.renameResults("Filename parsing");
}



macro "Take profile Action Tool - Cf00P0d417dadff0C0b0P0f4277a8bcff0" {
 	takeProfile();
	}


macro "Take profile [x]" {
 	takeProfile();
}
 	
function takeProfile() {
	k = nResults;
 	if (delim!="") {
		title = split(getTitle(), delim);
	}
	else {
		title = newArray(1);
		title[0] = getTitle();
	}
	
	//Get profile data
	getSelectionCoordinates(x, y);
	getPixelSize(unit, pixelWidth, pixelHeight);
  	profileC1 = getProfile();
	run("Next Slice [>]");
  	profileC2 = getProfile();
  	run("Previous Slice [<]");

	//Compute length of profile
	x0 = x[0]*pixelWidth;
	x1 = x[1]*pixelWidth;
	y0 = y[0]*pixelHeight;
	y1 = y[1]*pixelHeight;
	length = sqrt((x1-x0)*(x1-x0)+(y1-y0)*(y1-y0));
	
	//Obtain x-coordinate vector in microns
	xt = newArray(profileC1.length);
	for (j=0; j<profileC1.length; j++) xt[j] = length/profileC1.length*j;

	//X-transformation by maximum of FM4 signal
	tolerance = 50;
	profMax = Array.findMaxima(profileC2, tolerance);
	FM4maxX = xt[profMax[0]];
	FM4maxY = profileC2[profMax[0]];
  	for (n=0; n < xt.length; n++) xt[n] = xt[n] - FM4maxX;

  	//GFP normalisation (by mean from 10 % of highest values)
  	GFPmax = 0;
  	p = 0;
  	Array.getStatistics(profileC1, min, max);
  	for (n=0; n < profileC1.length; n++) if (profileC1[n] > 0.9*max) {
  		GFPmax = GFPmax + profileC1[n];
  		p++;
  	}
  	GFP = profileC1;
  	for (n=0; n < profileC1.length; n++) GFP[n] = profileC1[n]/GFPmax*p;
  	
  	//FM4 normalisation
  	FM4 = profileC2;
	for (n=0; n < profileC2.length; n++) FM4[n] = profileC2[n]/FM4maxY;
  	
  	for (j=0; j<profileC1.length; j++) {
  		setResult("X", j+k, xt[j]);
  		setResult("GFP", j+k, GFP[j]);
  		setResult("FM4", j+k, FM4[j]);
  		setResult("i", j+k, i);
  		for (e=0; e < export.length; e++) if (parseInt(export[e]) < title.length) setResult("Fac_"+e,j+k,title[export[e]]);
  		}
  	updateResults;
  	print("Added "+j+"values");
  	
  	selectWindow("Results");
	i = i + 1;
}



macro "Profile filtering setup [f2]" {
	do {
		Dialog.create("Profile measurements filtering");
		Dialog.addMessage("First channel (GFP)");
		Dialog.addMessage("Remove measurements with an excessive extracellular signal");
		Dialog.addNumber("Discard measurements with relative values greater than:", filterY[0]);
		Dialog.addNumber("at x-coordinates lower than:", filterX[0], 2, 5, "um");
	
		Dialog.addMessage("");
		Dialog.addMessage("Second channel (FM4)");
		Dialog.addMessage("Remove measurements with an excessive extracellular signal");
		Dialog.addNumber("Discard measurements with relative values greater than:", filterY[1]);
		Dialog.addNumber("at x-coordinates lower than:", filterX[1], 2, 5, "um");
		Dialog.addMessage("Remove measurements with an excessive intracellular signal");
		Dialog.addNumber("Discard measurements with relative values greater than:", filterY[2]);
		Dialog.addNumber("at x-coordinates greater than:", filterX[2], 2, 5, "um");
			
		Dialog.show();

		filtering = "";
		data = "profile";
		for (c=0; c<3; c++) {
			filterY[c] = Dialog.getNumber();
			filterX[c] = Dialog.getNumber();
			if (filterY[c] != filterY0[c]) {
				newData = "filtered_"+c;
				filtering = filtering+"\n"+newData+" <- filter("+data+", channel = \""+filterChannel[c]+"\", "+filterMode[c]+" = "+filterX[c]+", greater ="+filterY[c]+")";
				data = newData;
			}
		}
		filtering = filtering+"\nfiltered <- "+data;

		OK = getBoolean("R commands for filtering:\n\n"+filtering, "OK", "Back");
	} while (OK==false);
	
}




macro "Create model [f3]" {
	do {
		Dialog.create("Set analysis");
		Dialog.addCheckbox("Use filtering for input data?", filterModel);
		Dialog.addRadioButtonGroup("Data to analyze", newArray("Results","Single file", "All files in directory"), 3, 1, calibration);
		Dialog.addMessage("Fitting parameters for prediction");
		Dialog.addNumber("Prediction start [um]:", predFrom);
		Dialog.addNumber("Prediction end [um]:", predTo);
		Dialog.addNumber("Prediction step [um]:", predStep);
		Dialog.addMessage("Fluorescence parameters");
		Dialog.addNumber("GFP excitation wavelength [um]:", lambdaExGFP);	
		Dialog.addNumber("FM4 excitation wavelength [um]:", lambdaExFM4);
		Dialog.addMessage("");
		Dialog.addNumber("GFP emission wavelength [um]:", lambdaEmGFP);
		Dialog.addNumber("FM4 emission wavelength [um]:", lambdaEmFM4);
		Dialog.addString("Output file prefix", fileModel);
		Dialog.addCheckbox("Plot model?", plotModel);
		Dialog.addCheckbox("Pdf output?", pdfModel);
		Dialog.show();
		filterModel = Dialog.getCheckbox();
		calibration = Dialog.getRadioButton();
		predFrom = Dialog.getNumber();
		predTo = Dialog.getNumber();
		predStep = Dialog.getNumber();
		lambdaExGFP = Dialog.getNumber();
		lambdaExFM4 = Dialog.getNumber();
		lambdaEmGFP = Dialog.getNumber();
		lambdaEmFM4 = Dialog.getNumber();
		fileModel = Dialog.getString();
		plotModel = Dialog.getCheckbox();
		pdfModel = Dialog.getCheckbox();

		modeling = "library(peripheral)";
		if (calibration=="Single file") {
			ff = File.openDialog("Choose a .csv profile data file...");
			wd = File.directory;
			if (matches(sys, ".*Windows.*")) {
				ffw=replace(ff,"\\","/");
				modeling = modeling+"\nprofile <- read.profile(file=\""+ffw+"\")";
			} else {
				modeling = modeling+"\nprofile <- read.profile(file=\""+ff+"\")";
			}
		}
		if (calibration=="All files in directory") {
			wd = getDirectory("Choose a directory with .csv profile data files...");
			if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				modeling = modeling+"\nprofile <- read.profile(dir=\""+wdw+"\")";
			} else {
				modeling = modeling+"\nprofile <- read.profile(dir=\""+wd+"\",)";
			}
		}
		if (calibration=="Results") {
			selectWindow("Results");
			saveAs("Results");
			IJ.renameResults("Saved profiles");
			ff = File.directory+File.name;
			wd = File.directory;
			if (matches(sys, ".*Windows.*")) {
				ffw=replace(ff,"\\","/");
				modeling = modeling+"\nprofile <- read.profile(file=\""+ffw+"\")";
			} else {
				modeling = modeling+"\nprofile <- read.profile(file=\""+ff+"\")";
			}
		}
		if (filterModel == true) {
			modeling = modeling+"\n"+filtering;	
		} else {
			modeling = modeling+"\nfiltered <- profile";
		}
		modeling = modeling+"\nmp <- model(filtered, predFrom = "+predFrom+", predTo = "+predTo+", predStep = "+predStep+", lambdaEmFM4 = "+lambdaEmFM4+", lambdaEmGFP = "+lambdaEmGFP+", lambdaExFM4 = "+lambdaExFM4+", lambdaExGFP = "+lambdaExGFP+")";
		modeling = modeling+"\nprint(mp)";
		modeling = modeling+"\nsummary(mp)";
		
		if (plotModel == true) {
			if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				modeling = modeling+"\npng(\""+wdw+fileModel+".png\", width=800, height = 600)\nplot(mp)\ndev.off()";
			} else {
				modeling = modeling+"\npng(\""+wd+fileModel+".png\", width=800, height = 600)\nplot(mp)\ndev.off()";
			}
		}
		if (pdfModel == true) {
			if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				modeling = modeling+"\npdf(\""+wdw+fileModel+".pdf\", width=10, height = 8)\nplot(mp)\ndev.off()";
			} else {
				modeling = modeling+"\npdf(\""+wd+fileModel+".pdf\", width=10, height = 8)\nplot(mp)\ndev.off()";
			}
		}
		model = wd+fileModel+".RData";
		if (matches(sys, ".*Windows.*")) {
				modelw=replace(model,"\\","/");
				modeling = modeling+"\nsave(mp,file=\""+modelw+"\")";
			} else {
				modeling = modeling+"\nsave(mp,file=\""+model+"\")";
			}
		OK = getBoolean("R commands for a model creation:\n \n"+modeling, "OK", "Back");
	} while (OK==false);
	
	Rs = wd+fileModel+".R";
	Ro = wd+fileModel+".Rout";
	File.saveString(modeling, Rs);
	
	if (matches(sys, ".*Windows.*")) {
		showStatus("Runing: "+r+" CMD BATCH "+Rs+" "+Ro+" ...");
		exec(r+" CMD BATCH "+Rs+" "+Ro);
	} else {
		showStatus("Runing: R CMD BATCH "+Rs+" "+Ro+" ...");
		exec("R CMD BATCH "+Rs+" "+Ro);
	}
	showStatus("Finnished");
	run("Text File... ", "open="+Ro);
	if (plotModel == true) {
		open(wd+fileModel+".png");
	}
	
}


			
macro "Calculate distribution [f4]" {
	do {
		Dialog.create("Set analysis");
		Dialog.addCheckbox("Use filtering for input data?", filterProfile);
		Dialog.addRadioButtonGroup("Data to analyze", newArray("Results","Single file", "All files in directory"), 3, 1, selectData);
		Dialog.addRadioButtonGroup("Select model", newArray("Recent result","From file"), 2, 1, selectModel);
		Dialog.addString("Output file prefix", fileDistrib);
		Dialog.addCheckbox("Remove results with residual variability", filterDistrib);
		Dialog.addNumber("greater than:", cutOff);
		Dialog.addCheckbox("Plot results?", plotDistrib);
		Dialog.addMessage("Select sample grouping factors for plotting\n(selection of non-existing levels cause error)");
		Dialog.addCheckboxGroup(variantsBoxplot.length, 1, newArray("Fac_0", "Fac_1", "Fac_2", "Fac_3", "Fac_4"), variantsBoxplot);
		Dialog.addCheckbox("Pdf output?", pdfDistrib);
	
		Dialog.show();
		filterProfile = Dialog.getCheckbox();
		selectData = Dialog.getRadioButton();
		selectModel = Dialog.getRadioButton();
		fileDistrib = Dialog.getString();
		filterDistrib = Dialog.getCheckbox();
		cutOff = Dialog.getNumber();
		plotDistrib = Dialog.getCheckbox();
		variants = "c(";
		for (n=0; n<variantsBoxplot.length; n++) {
			variantsBoxplot[n] = Dialog.getCheckbox();
			if (variantsBoxplot[n] == true) {
				v = n + 2;
				if (variants != "c(") variants = variants+",";
				variants = variants+"\"var"+v+"\"";
			}
		}
		variants = variants+")";
		pdfDistrib = Dialog.getCheckbox();
	
		distribution = "library(peripheral)";
	
		// Read input data
		if (selectData=="Single file") {
			ff = File.openDialog("Choose the .csv data file...");
			wd = File.directory;
			if (matches(sys, ".*Windows.*")) {
				ffw=replace(ff,"\\","/");
				distribution = distribution+"\nprofile <- read.profile(file=\""+ffw+"\")";
			} else {
				distribution = distribution+"\nprofile <- read.profile(file=\""+ff+"\")";
			}
		}
		if (selectData=="All files in directory") {
			wd = getDirectory("Choose a directory with data files");
			if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				distribution = distribution+"\nprofile <- read.profile(dir=\""+wdw+"\",)";
			} else {
				distribution = distribution+"\nprofile <- read.profile(dir=\""+wd+"\",)";
			}
		}
		if (selectData=="Results") {
			selectWindow("Results");
			saveAs("Results");
			IJ.renameResults("Saved profiles");
			ff = File.directory+File.name;
			wd = File.directory;
			if (matches(sys, ".*Windows.*")) {
				ffw=replace(ff,"\\","/");
				distribution = distribution+"\nprofile <- read.profile(file=\""+ffw+"\")";
			} else {
				distribution = distribution+"\nprofile <- read.profile(file=\""+ff+"\")";
			}
		}
		
		// Read model
		if (selectModel=="From file") {
			mf = File.openDialog("Choose the .RData file with model...");
			if (matches(sys, ".*Windows.*")) {
				mfw=replace(mf,"\\","/");
				distribution = distribution+"\nload(\""+mfw+"\")";
			} else {
				distribution = distribution+"\nload(\""+mf+"\")";
			}
		}
		if (selectModel=="Recent result") {
			if (model == "") {
				showMessage("Recent model does not exist, select model from file");
				mf = File.openDialog("Choose the .RData file with model...");
			} else {
				mf = model;
			}
			if (matches(sys, ".*Windows.*")) {
				mfw=replace(mf,"\\","/");
				distribution = distribution+"\nload(\""+mfw+"\")";
			} else {
				distribution = distribution+"\nload(\""+mf+"\")";
			}	
		}

		// Filter input data
		if (filterProfile == true) {
			distribution = distribution+"\n"+filtering;	
		} else {
			distribution = distribution+"\nfiltered <- profile";
		}
		
		// Compute distribution
		distribution = distribution+"\nmd <- distrib(filtered, mp)";

		// Filter results
		if (filterDistrib == true) {
			distribution = distribution+"\nmdf <- filter(md, cut.off = "+cutOff+")";	
		} else {
			distribution = distribution+"\nmdf <- md";
		}
		
		// Print results
		distribution = distribution+"\nprint(mdf)";
		distribution = distribution+"\nsummary(mdf)";
		if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				distribution = distribution+"\ndf <- data.frame(rownames(mdf$affinity), mdf$affinity)\ncolnames(df) <- c(\" \", colnames(mdf$affinity))\nwrite.csv(df, file = \""+wdw+fileDistrib+".csv\", row.names = FALSE, quote = FALSE)";
			} else {
				distribution = distribution+"\ndf <- data.frame(rownames(mdf$affinity), mdf$affinity)\ncolnames(df) <- c(\" \", colnames(mdf$affinity))\nwrite.csv(df, file = \""+wd+fileDistrib+".csv\", row.names = FALSE, quote = FALSE)";
			}
		
		// Create plots
		if (plotDistrib == true) {
			if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				distribution = distribution+"\npng(\""+wdw+fileDistrib+".png\", width=800, height = 600)\nboxplot(mdf, variants="+variants+")\ndev.off()";
			} else {
				distribution = distribution+"\npng(\""+wd+fileDistrib+".png\", width=800, height = 600)\nboxplot(mdf, variants="+variants+")\ndev.off()";
			}
		}
		if (pdfDistrib == true) {
			if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				distribution = distribution+"\npdf(\""+wdw+fileDistrib+".pdf\", width=10, height = 8)\nboxplot(mdf, variants="+variants+")\ndev.off()";
			} else {
				distribution = distribution+"\npdf(\""+wd+fileDistrib+".pdf\", width=10, height = 8)\nboxplot(mdf, variants="+variants+")\ndev.off()";
			}
		} 
		OK = getBoolean("R commands for a distribution computing:\n \n"+distribution, "OK", "Back");
	} while (OK==false);
	
	// Generate R script
	Rs = wd+fileDistrib+".R";
	Ro = wd+fileDistrib+".Rout";
	File.saveString(distribution, Rs);
	
	// Running R script
	if (matches(sys, ".*Windows.*")) {
		showStatus("Runing: "+r+" CMD BATCH "+Rs+" "+Ro+" ...");
		exec(r+" CMD BATCH "+Rs+" "+Ro);
	} else {
		showStatus("Runing: R CMD BATCH "+Rs+" "+Ro+" ...");
		exec("R CMD BATCH "+Rs+" "+Ro);
	}
	showStatus("Finnished");
	
	// Load R outputs
	run("Text File... ", "open="+Ro);
	if (plotDistrib == true) {
		open(wd+fileDistrib+".png");
	}
	run("Table... ", "open="+wd+fileDistrib+".csv");
	
}




macro "Plot profile data [f5]" {
	do {
		Dialog.create("Set plotting");
		Dialog.addCheckbox("Use filtering for input data?", filterPlot);
		Dialog.addRadioButtonGroup("Data to analyze", newArray("From >Results< window","From >Saved profiles< window","Single file", "All files in directory"), 4, 1, selectPlot);
		Dialog.addMessage("Select sample grouping factors for plotting\n(selection of non-existing levels cause error)");
		Dialog.addCheckboxGroup(variantsPlot.length, 1, newArray("i","Fac_0", "Fac_1", "Fac_2", "Fac_3", "Fac_4"), variantsPlot);
		Dialog.addString("Output file prefix", filePlot);
		Dialog.addNumber("Plot width:", plotWidth, 0, 5, "px");
		Dialog.addNumber("Plot height:", plotHeight, 0, 5, "px");
		Dialog.addCheckbox("Pdf output?", pdfPlot);
	
		Dialog.show();
		filterPlot = Dialog.getCheckbox();
		selectPlot = Dialog.getRadioButton();
		variants = "c(";
		for (n=0; n<variantsPlot.length; n++) {
			variantsPlot[n] = Dialog.getCheckbox();
			if (variantsPlot[n] == true) {
				v = n + 1;
				if (variants != "c(") variants = variants+",";
				variants = variants+"\"var"+v+"\"";
			}
		}
		variants = variants+")";
		filePlot = Dialog.getString();
		plotWidth = Dialog.getNumber();
		plotHeight = Dialog.getNumber();
		pdfPlot = Dialog.getCheckbox();
	
		plotting = "library(peripheral)";
	
		// Read input data
		if (selectPlot=="Single file") {
			ff = File.openDialog("Choose the .csv data file...");
			wd = File.directory;
			if (matches(sys, ".*Windows.*")) {
				ffw=replace(ff,"\\","/");
				plotting = plotting+"\nprofile <- read.profile(file=\""+ffw+"\")";
			} else {
				plotting = plotting+"\nprofile <- read.profile(file=\""+ff+"\")";
			}
		}
		if (selectPlot=="All files in directory") {
			wd = getDirectory("Choose a directory with data files");
			if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				plotting = plotting+"\nprofile <- read.profile(dir=\""+wdw+"\",)";
			} else {
				plotting = plotting+"\nprofile <- read.profile(dir=\""+wd+"\",)";
			}
		}
		if (selectPlot=="From >Results< window") {
			selectWindow("Results");
			saveAs("results");
			IJ.renameResults("Saved profiles");
			ff = File.directory+File.name;
			wd = File.directory;
			if (matches(sys, ".*Windows.*")) {
				ffw=replace(ff,"\\","/");
				plotting = plotting+"\nprofile <- read.profile(file=\""+ffw+"\")";
			} else {
				plotting = plotting+"\nprofile <- read.profile(file=\""+ff+"\")";
			}
		}
		if (selectPlot=="From >Saved profiles< window") {
			selectWindow("Saved profiles");
			saveAs("results");
			IJ.renameResults("Saved profiles");
			ff = File.directory+File.name;
			wd = File.directory;
			if (matches(sys, ".*Windows.*")) {
				ffw=replace(ff,"\\","/");
				plotting = plotting+"\nprofile <- read.profile(file=\""+ffw+"\")";
			} else {
				plotting = plotting+"\nprofile <- read.profile(file=\""+ff+"\")";
			}
		}
		// Filter input data
		if (filterPlot == true) {
			plotting = plotting+"\n"+filtering;	
		} else {
			plotting = plotting+"\nfiltered <- profile";
		}
		
		// Create plots
		if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				plotting = plotting+"\npng(\""+wdw+filePlot+".png\", width="+plotWidth+", height = "+plotHeight+")\nplot(filtered, variants="+variants+")\ndev.off()";
			} else {
				plotting = plotting+"\npng(\""+wd+filePlot+".png\", width="+plotWidth+", height = "+plotHeight+")\nplot(filtered, variants="+variants+")\ndev.off()";
			}
		if (pdfPlot == true) {
			if (matches(sys, ".*Windows.*")) {
				wdw=replace(wd,"\\","/");
				plotting = plotting+"\npdf(\""+wdw+filePlot+".pdf\", width=10, height = 8)\nplot(filtered, variants="+variants+")\ndev.off()";
			} else {
				plotting = plotting+"\npdf(\""+wd+filePlot+".pdf\", width=10, height = 8)\nplot(filtered, variants="+variants+")\ndev.off()";
			}
		}
		Rs = wd+filePlot+".R";
		Ro = wd+filePlot+".Rout";
		OK = getBoolean("R commands for a plot creating:\n \n"+plotting+"\n\nRuning: R "+r+" CMD BATCH "+Rs+" "+Ro+" ...", "OK", "Back");
	} while (OK==false);
	
	// Generate R script
	File.saveString(plotting, Rs);
	
	// Running R script
	if (matches(sys, ".*Windows.*")) {
		showStatus("Runing: "+r+" CMD BATCH "+Rs+" "+Ro+" ...");
		exec(r+" CMD BATCH "+Rs+" "+Ro);
	} else {
		showStatus("Runing: R CMD BATCH "+Rs+" "+Ro+" ...");
		exec("R CMD BATCH "+Rs+" "+Ro);
	}
	showStatus("Finnished");
	
	// Load R outputs
	run("Text File... ", "open="+Ro);
	open(wd+filePlot+".png");
	
	
}


var prikazy = newMenu("Peripheral Protein Menu Tool", newArray("Import options [f1]", "Take profile [x]", "Profile filtering setup [f2]", "Create model [f3]", "Calculate distribution [f4]", "Plot profile data [f5]", "-", "Help [f10]"));


macro "Peripheral Protein Menu Tool - C0b0T0b13PCf00T8b13M" {
      cmd = getArgument();
      if (cmd!="-") run(cmd);
  }